In order to get access to change the "Channel Box" menu, we need to know the location. Open up the file generateChannelMenu.mel located on a windows based machine at: C:/Program Files/Autodesk/Maya8.5/scripts/startup/

Important Note:
Please read the disclaimer at the top of the page, by following the rest of the tutorial you are bound by the license agreement with Autodesk since you will be editing the file, rather then downloading the full version here. Therefore, granting me (meljunky) no responsibility of any damages that may occur from using the new version of the script.

To prevent any problems that may occur with editing Maya's startup scripts. Please save the file in your scripts directory, this will create a backup, for example: C:/Documents and Settings/Admin/My Documents/maya/8.5/scripts

When Maya starts, the generateChannelMenu.mel located in your scrips directory will take precedence over the file located in the startup directory. If you make any mistakes, the original file is backed up safely.

At the beginning of the file for for a global procedure called channelBoxCommand. Add the following code to the existing switch statement. The new switch statement will now include a new case called "-graphSelected". The code will be executed when the new option "Graph Selected Nodes" is executed.

  case "-graphSelected":
    string $connections[];
    string $sel[] = `ls -sl`;
    if ( size(`ls -sl`) == 0 ){
            warning "No nodes are selected.";
            return;
    }
    string $channels[] = `channelBox -q -sma mainChannelBox`;
    select -cl; //Clear Selection
    for ($do in $channels){
    select -tgl `listConnections ($sel[0] + "." + $do)`;
    }
    if ( size(`ls -sl`) ){
            hyperGraphWindow "" DG; //Opens a new Hypergraph
            $whichPanel = getHyperGraphPanel("DG"); //Determine which panel is selected
            string $hyperGraphEd = ($whichPanel + "HyperGraphEd");
            hyperGraphDepthSet($hyperGraphEd, 1); //Change depth to 1
    }else{
            warning "No input connections for selected channels";
            select -r $sel;
    }

    break;

Now, the new option needs to be created. Find the global procedure callled generateChannelMenu, near the bottom of the script. Inside that procedure is the following line:

menuItem -label (uiRes("m_generateChannelMenu.kKeySelected")) -c "channelBoxCommand -key" keyItem;

Add the following line above:

menuItem -label "Graph Selected Channels" -c "channelBoxCommand -graphSelected" graphSelected;

It will now look like:

menuItem -label "Graph Selected Channels" -c "channelBoxCommand -graphSelected" graphSelected;
menuItem -label (uiRes("m_generateChannelMenu.kKeySelected")) -c "channelBoxCommand -key" keyItem;

The new change will not take in effect until after you restart Maya. Congratulations, you edited the RMC menu for the "Channel Box". This should get you on your way to adding new menu options to Maya's RMC "Channel Box" Menu.